开源bat强大的批处理实现禁用或隐藏系统盘分区

用bat来实现对分区的隐藏和禁用。（这里是利用系统机制）

将下面的所有内容保存为bat文件，运行。

@echo off
mode con cols=45 lines=17
echo.
title 禁用或隐藏任意分区 by JFKJ
set l1=        如果需要继续其他操作请选择y
set l2=             按任意键退出,感谢使用!
:main
cls
color 0A
echo.
echo              隐藏或禁用任意分区
echo.
echo      [ 重庆市万州区静枫科技出品制作 ]
echo    注意:运行此操作会有一定的危险性请慎用
echo    隐藏和禁用,不会对系统造成任何不良影响
echo    如有疑问或者BUG请及时反馈QQ:845532699 
echo.
echo          1. 禁用任意分区
echo          2. 解除禁用任意分区
echo          3. 隐藏任意分区
echo          4. 解除隐藏任意分区
echo          5. 按任意键退出
echo.
SET verybat=
SET /P verybat=     请选择要进行的操作：  
IF /I '%verybat:~0,1%'=='1' GOTO 1
IF /I '%verybat:~0,1%'=='2' GOTO 2
IF /I '%verybat:~0,1%'=='3' GOTO 3
IF /I '%verybat:~0,1%'=='4' GOTO 4
exit
:1
cls
color 4f
set regadd=reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
echo.&echo.&echo.&echo.
set /p dirv1=    请选择你要禁用的分区：
set num=2
set str=c d e f g h i j k l m n o p q r s t u v w x y z
for %%i in (%str%) do (
    set /a num*=2
    if /i "%%i"=="%dirv1%" goto forbid
)
:forbid
%regadd% /v NoViewOnDrive /t REG_DWORD /d %num% /f
gpupdate.exe /force >nul
cls
echo.
echo         已成功禁用了"%dirv1%:"分区
echo. && echo %l1% && echo. && echo %l2% && echo.
set jx=
set /p jx=  请选择：
if /i "%jx%"=="y" goto main
exit
:2
reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoViewOnDrive /f >nul 2>nul
gpupdate /force >nul
cls
color 2f
echo.
echo   已成功解除任意分区的禁用。
echo. && echo %l1% && echo. && echo %l2% && echo.
set jx=
set /p jx=  请选择：
if /i "%jx%"=="y" goto main
exit
:3
set regadd=reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
cls
color f9
echo.&echo.&echo.&echo.
set /p dirv2=    请选择你要隐藏的分区：
set num=2
set str=c d e f g h i j k l m n o p q r s t u v w x y z
for %%i in (%str%) do (
    set /a num*=2
    if /i "%%i"=="%dirv2%" goto hide
)
:hide
%regadd% /v NoDrives /t REG_DWORD /d %num% /f
gpupdate /force >nul
cls
color f5
echo.
echo       已成功隐藏了"%dirv2%:"分区
echo. && echo %l1% && echo. && echo %l2% && echo.
set jx2=
set /p jx2=  请选择：
if /i "%jx2%"=="y" goto main
exit
:4
cls
color 1f
reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDrives /f >nul 2>nul
gpupdate /force >nul
echo.
echo      已成功解除任意分区的隐藏。
echo. && echo %l1% && echo. && echo %l2% && echo.
set jx2=
set /p jx2=  请选择：
if /i "%jx2%"=="y" goto main
exit